[비동기] Springboot 3.X.X 버전에서 JPA, QueryDSL 사용 ( Q엔티티 생성 안됨 )

문제 상황

이전에 프로젝트할 당시 사용했던 JPA, QueryDSL 코드를 새로운 프로젝트에 적용하려다가

EntityManager 관련 에러와 Q엔티티가 만들어지지 않는 에러가 발생하였다.

 

해결 방법

- SpringBoot 3버전 이상은 QueryDsl 세팅이 변경되었다. 변경된 방법으로 선언해주자.

 

해결 과정

기존에는 build.gradle에 아래와 같이 선언해주었는데, 

implementation "com.querydsl:querydsl-jpa"

이제는 jakarta 패키지를 사용하겠다고 명시를 해줘야 한다.

implementation "com.querydsl:querydsl-jpa:5.0.0:jakarta"
annotationProcessor "com.querydsl:querydsl-apt:${dependencyManagement.importedProperties['querydsl.version']}:jakarta"

 

JPA에서 사용되는 Entity 등의 어노테이션이 javax -> jakarta 로 패키지가 이동하였다.

때문에 javax/persistence/entity 에러와 같이 javax 관련 에러가 발생할 수 있다.

때문에 위와 같이 jakarta를 같이 명시해줘야 한다.

 

 

전체 build.gradle

plugins {
    id 'java'
    id 'org.springframework.boot' version '3.1.3'
    id 'io.spring.dependency-management' version '1.1.3'
}

group = 'com.async.myapp'
version = '0.0.1-SNAPSHOT'

java {
    sourceCompatibility = '17'
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa' //jpa
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.projectlombok:lombok:1.18.22'
    annotationProcessor 'org.projectlombok:lombok' //add
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    //mysql
    runtimeOnly 'com.mysql:mysql-connector-j'

    //swagger 사용
    implementation group: 'io.springfox', name: 'springfox-swagger2', version: '2.9.2'
    implementation group: 'io.springfox', name: 'springfox-swagger-ui', version: '2.9.2'

    //webClient 사용 - http 요청
    implementation 'org.springframework.boot:spring-boot-starter-webflux'

    //querydsl 추가 1
    implementation "com.querydsl:querydsl-jpa:${dependencyManagement.importedProperties['querydsl.version']}:jakarta"
    annotationProcessor "com.querydsl:querydsl-apt:${dependencyManagement.importedProperties['querydsl.version']}:jakarta"
    // java.lang.NoClassDefFoundError (javax.annotation.Generated) 대응 코드
    annotationProcessor "jakarta.annotation:jakarta.annotation-api"
    // java.lang.NoClassDefFoundError (javax.annotation.Entity) 대응 코드
    annotationProcessor "jakarta.persistence:jakarta.persistence-api"

}

//querydsl 추가 2
def generated = 'src/main/generated'    //QClass 파일 생성 위치
sourceSets {
    main.java.srcDirs += [generated]	//java source set에 querydsl QClass 위치 추가
}
tasks.withType(JavaCompile){			//QClass 파일 생성 위치를 지정
    options.getGeneratedSourceOutputDirectory().set(file(generated))
}
clean{
    delete file(generated)  			//gradle clean 시 generated 디렉토리 삭제
}